文字搬动效果

package {
	//导入所需的类
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.text.TextField;
	public class MovingText extends Sprite
	{
		//文本框对象
		private var txt:TextField;
		//需要移动的文字
		private var info:String;
		//循环计数，用于控制移动的速度
		private var i:uint;
		//取子串计数器，根据改变了取子串
		private var ti:uint;
		public function MovingText()
		{
			//创建文本矿对象并设置相关属性
			txt=new TextField();
			txt.width=100;//设置宽度
			txt.textColor=0x6F6F6F;//设置文字颜色
			txt.selectable=false;//设置是否可被选中
			//设置文本框位置
			txt.x=10;
			txt.y=100;
			//把文本框加入 当前影片
			this.addChild(txt);
			
			//设置移动的文字内容
			info="There is no way that a bee could bee able to fly.";
			//使用操作符连接字符串
			info+="Their wings are too small to get it's fat little body off the ground.";
			
			//初始化计数器
			i=0;
			ti=0;
			//增加监听事件
			this.addEventListener(Event.ENTER_FRAME,enterFrame);
		}
		public function enterFrame(e:Event):void
		{
			i++;//使i增加1
			if(i==3)//改变数字控制一定速度
			{
				//取字串
				txt.text=info.substr(++ti,20);
				i=0;//重设i的值
				//当播放完一次后重新开始播放
				if(ti>=info.length) ti=0;
			}
		}
	}
}